vineyard

{

  inputs.nixpkgs.url = "github:NixOS/nixpkgs/2c423e03bbafcff28bfadc6781a4a8257f205cb5";

  outputs = { self, nixpkgs }: let

    systems = [ "x86_64-linux" "aarch64-linux" ];

    forAllSystems = nixpkgs.lib.genAttrs systems;

    packageFor = system: let

      pkgs = nixpkgs.legacyPackages.${system};

    in pkgs.rustPlatform.buildRustPackage {

      pname = "vineyard";

      version = "0.1.0";

      src = pkgs.lib.cleanSourceWith {

        src = ./.;

        filter = path: type:

          pkgs.lib.cleanSourceFilter path type

          && !(type == "directory" && builtins.elem (builtins.baseNameOf path) [ "target" ".jj" ".git" ]);

      };

      cargoLock.lockFile = ./Cargo.lock;

      doCheck = true;

    };

  in {

    nixosModules.default = import ./nix/module.nix self;

    nixosModules.vineyard = self.nixosModules.default;

    packages = forAllSystems (system: {

      default = packageFor system;

      vineyard = packageFor system;

    });

    checks = forAllSystems (system: {

      vineyard = packageFor system;

    });

    devShells = forAllSystems (system: let

      pkgs = nixpkgs.legacyPackages.${system};

    in {

      default = pkgs.mkShell {

        packages = with pkgs; [ cargo rustc rustfmt clippy pkg-config ];

      };

    });

  };

}