roundabout

self:

{

  config,

  lib,

  pkgs,

  ...

}:

let

  cfg = config.programs.roundabout;

  toml = pkgs.formats.toml { };

  plugin = pkgs.callPackage ./plugin.nix { roundabout = cfg.package; };

  codexPlugin = pkgs.callPackage ./codex-plugin.nix { roundabout = cfg.package; };

  ompPlugin = pkgs.callPackage ./omp-plugin.nix { roundabout = cfg.package; };

in

{

  options.programs.roundabout = {

    enable = lib.mkEnableOption "roundabout, build admission for agents";

    package = lib.mkOption {

      type = lib.types.package;

      default = self.packages.${pkgs.stdenv.hostPlatform.system}.roundabout;

      defaultText = lib.literalExpression "roundabout.packages.\${system}.roundabout";

      description = "the roundabout package";

    };

    socketActivation = lib.mkOption {

      type = lib.types.bool;

      default = true;

      description = ''

        let a systemd user socket own `$XDG_RUNTIME_DIR/roundabout.sock` and start the

        daemon on demand. when disabled, the first client spawns daemon instead

      '';

    };

    settings = lib.mkOption {

      inherit (toml) type;

      default = { };

      example = lib.literalExpression ''

        {

          budget.ram = "16GiB";

          enforce.unwrapped = "wrap";

          artifacts.stop = "block";

        }

      '';

      description = ''

        written to `/etc/roundabout/config.toml`, which anyone without a

        `~/.config/roundabout/config.toml` of their own gets. see readme

      '';

    };

    claude = {

      hooks = lib.mkOption {

        type = lib.types.attrs;

        readOnly = true;

        default = import ./hooks.nix {

          inherit lib;

          roundabout = cfg.package;

        };

        defaultText = lib.literalMD "roundabout's hooks, keyed by event";

        description = ''

          hooks in `settings.json` shape, for whatever writes your claude config.

          lists concatenate under the json format type, so they sit alongside

          hooks you already have

        '';

      };

      skill = lib.mkOption {

        type = lib.types.path;

        readOnly = true;

        default = "${plugin}/plugins/roundabout/skills/roundabout";

        defaultText = lib.literalMD "the roundabout skill directory";

        description = "the skill directory, for configs that manage `~/.claude/skills` themselves";

      };

      plugin = lib.mkOption {

        type = lib.types.package;

        readOnly = true;

        default = plugin;

        defaultText = lib.literalMD "the roundabout plugin marketplace";

        description = "hooks and skill as a marketplace, for `claude plugin marketplace add`";

      };

    };

    codex = {

      hooks = lib.mkOption {

        type = lib.types.attrs;

        readOnly = true;

        default = import ./codex-hooks.nix {

          inherit lib;

          roundabout = cfg.package;

        };

        defaultText = lib.literalMD "roundabout's Codex hooks, keyed by event";

        description = "hooks in Codex hooks.json shape, for configs that manage Codex themselves";

      };

      skill = lib.mkOption {

        type = lib.types.path;

        readOnly = true;

        default = "${codexPlugin}/plugins/roundabout/skills/roundabout";

        defaultText = lib.literalMD "the roundabout skill directory for Codex";

        description = "the skill directory, for configs that manage Codex skills themselves";

      };

      plugin = lib.mkOption {

        type = lib.types.package;

        readOnly = true;

        default = codexPlugin;

        defaultText = lib.literalMD "the roundabout Codex plugin marketplace";

        description = "hooks and skill as a marketplace for Codex";

      };

    };

    omp = {

      plugin = lib.mkOption {

        type = lib.types.package;

        readOnly = true;

        default = ompPlugin;

        defaultText = lib.literalMD "the roundabout OMP plugin";

        description = "the extension and skill for omp plugin link";

      };

      skill = lib.mkOption {

        type = lib.types.path;

        readOnly = true;

        default = "${ompPlugin}/skills/roundabout";

        defaultText = lib.literalMD "the roundabout skill directory for OMP";

        description = "the skill directory, for configs that manage OMP skills themselves";

      };

    };

  };

  config = lib.mkIf cfg.enable {

    environment.systemPackages = [ cfg.package ];

    # a real file rather than the usual /etc/static symlink, so a rebuild

    # renames over it where the daemon's inotify watch can see

    environment.etc."roundabout/config.toml" = lib.mkIf (cfg.settings != { }) {

      source = toml.generate "roundabout-config.toml" cfg.settings;

      mode = "0444";

    };

    systemd.user.sockets.roundabout = lib.mkIf cfg.socketActivation {

      description = "roundabout build admission socket";

      wantedBy = [ "sockets.target" ];

      listenStreams = [ "%t/roundabout.sock" ];

      socketConfig.SocketMode = "0600";

    };

    systemd.user.services.roundabout = lib.mkIf cfg.socketActivation {

      description = "roundabout build admission daemon";

      serviceConfig.ExecStart = "${lib.getExe cfg.package} daemon";

    };

  };

}