roundabout

public

Star0

Fork 0

Watch0

7 commits 1 branch 0 tags 0 releases158.8 KiB

Commit `052a1a49371c`

tarball

atagen <boss@atagen.co>2026-09-27 03:59 UTC

5 files changed+139-16

nix: nixos module with socket activation and read-only claude hooks

The daemon runs from a systemd user socket by default. Whatever writes the claude settings can pull hooks, skill and plugin from programs.rabt.claude instead of going through claude plugin install. Hooks live in one file so the plugin and the module can't drift.

Modified file: README.md+10 additions@@ -31,6 +31,16 @@ claude plugin marketplace add ./result
 claude plugin install roundabout@roundabout
 ```
 
+or on nixos
+
+```nix
+imports = [ roundabout.nixosModules.default ];
+programs.roundabout.enable = true;
+programs.roundabout.settings.budget.ram = "16GiB";   # lands in /etc/roundabout/config.toml
+```
+
+that installs roundabout and a socket-activated systemd user unit for the daemon (`socketActivation = false` to let clients spawn it instead). `programs.roundabout.claude` has read-only `hooks`, `skill` and `plugin` for whatever writes your claude config, e.g. `settings.hooks = config.programs.roundabout.claude.hooks`.
+
 the plugin brings a skill and hooks. unwrapped builds get bounced back with instructions, overdue builds get mentioned to the agent that started them, and agents over their artifact cap get told to tidy up before they stop. `rabt` needs to be on PATH for the agent too, so install `.#roundabout` alongside.
 
 ## config

Modified file: flake.nix+2

@@ -16,6 +16,8 @@

1616 pkgsFor = system: nixpkgs.legacyPackages.${system};

1717 in

1818 {

19+ nixosModules.default = import ./nix/nixos-module.nix self;

20+

1921 packages = forAllSystems (

2022 system:

2123 let

Added file: nix/hooks.nix+20 additions@@ -0,0 +1,20 @@
+{ lib, roundabout }:
+
+let
+  hook = event: {
+    type = "command";
+    command = "${lib.getExe roundabout} hook ${event}";
+  };
+in
+{
+  PreToolUse = [
+    {
+      matcher = "Bash";
+      hooks = [ (hook "pre-tool-use") ];
+    }
+  ];
+  PostToolUse = [ { hooks = [ (hook "post-tool-use") ]; } ];
+  UserPromptSubmit = [ { hooks = [ (hook "prompt-submit") ]; } ];
+  Stop = [ { hooks = [ (hook "stop") ]; } ];
+  SubagentStop = [ { hooks = [ (hook "subagent-stop") ]; } ];
+}

Added file: nix/nixos-module.nix+106 additions@@ -0,0 +1,106 @@
+self:
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+let
+  cfg = config.programs.roundabout;
+  toml = pkgs.formats.toml { };
+  plugin = pkgs.callPackage ./plugin.nix { roundabout = cfg.package; };
+in
+{
+  options.programs.roundabout = {
+    enable = lib.mkEnableOption "roundabout, build admission for agents";
+
+    package = lib.mkOption {
+      type = lib.types.package;
+      default = self.packages.${pkgs.stdenv.hostPlatform.system}.roundabout;
+      defaultText = lib.literalExpression "roundabout.packages.\${system}.roundabout";
+      description = "the roundabout package";
+    };
+
+    socketActivation = lib.mkOption {
+      type = lib.types.bool;
+      default = true;
+      description = ''
+        let a systemd user socket own `$XDG_RUNTIME_DIR/roundabout.sock` and start the
+        daemon on demand. when disabled, the first client spawns daemon instead
+      '';
+    };
+
+    settings = lib.mkOption {
+      inherit (toml) type;
+      default = { };
+      example = lib.literalExpression ''
+        {
+          budget.ram = "16GiB";
+          enforce.unwrapped = "wrap";
+          artifacts.stop = "block";
+        }
+      '';
+      description = ''
+        written to `/etc/roundabout/config.toml`, which anyone without a
+        `~/.config/roundabout/config.toml` of their own gets. see readme
+      '';
+    };
+
+    claude = {
+      hooks = lib.mkOption {
+        type = lib.types.attrs;
+        readOnly = true;
+        default = import ./hooks.nix {
+          inherit lib;
+          roundabout = cfg.package;
+        };
+        defaultText = lib.literalMD "roundabout's hooks, keyed by event";
+        description = ''
+          hooks in `settings.json` shape, for whatever writes your claude config.
+          lists concatenate under the json format type, so they sit alongside
+          hooks you already have
+        '';
+      };
+
+      skill = lib.mkOption {
+        type = lib.types.path;
+        readOnly = true;
+        default = "${plugin}/plugins/roundabout/skills/roundabout";
+        defaultText = lib.literalMD "the roundabout skill directory";
+        description = "the skill directory, for configs that manage `~/.claude/skills` themselves";
+      };
+
+      plugin = lib.mkOption {
+        type = lib.types.package;
+        readOnly = true;
+        default = plugin;
+        defaultText = lib.literalMD "the roundabout plugin marketplace";
+        description = "hooks and skill as a marketplace, for `claude plugin marketplace add`";
+      };
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    environment.systemPackages = [ cfg.package ];
+
+    # a real file rather than the usual /etc/static symlink, so a rebuild
+    # renames over it where the daemon's inotify watch can see
+    environment.etc."roundabout/config.toml" = lib.mkIf (cfg.settings != { }) {
+      source = toml.generate "roundabout-config.toml" cfg.settings;
+      mode = "0444";
+    };
+
+    systemd.user.sockets.roundabout = lib.mkIf cfg.socketActivation {
+      description = "roundabout build admission socket";
+      wantedBy = [ "sockets.target" ];
+      listenStreams = [ "%t/roundabout.sock" ];
+      socketConfig.SocketMode = "0600";
+    };
+
+    systemd.user.services.roundabout = lib.mkIf cfg.socketActivation {
+      description = "roundabout build admission daemon";
+      serviceConfig.ExecStart = "${lib.getExe cfg.package} daemon";
+    };
+  };
+}

Modified file: nix/plugin.nix+1 additions−16 deletions@@ -6,24 +6,9 @@
 }:
 
 let
-  hook = event: {
-    type = "command";
-    command = "${lib.getExe roundabout} hook ${event}";
-  };
   hooks = writeText "hooks.json" (
     builtins.toJSON {
-      hooks = {
-        PreToolUse = [
-          {
-            matcher = "Bash";
-            hooks = [ (hook "pre-tool-use") ];
-          }
-        ];
-        PostToolUse = [ { hooks = [ (hook "post-tool-use") ]; } ];
-        UserPromptSubmit = [ { hooks = [ (hook "prompt-submit") ]; } ];
-        Stop = [ { hooks = [ (hook "stop") ]; } ];
-        SubagentStop = [ { hooks = [ (hook "subagent-stop") ]; } ];
-      };
+      hooks = import ./hooks.nix { inherit lib roundabout; };
     }
   );
   plugin = writeText "plugin.json" (

roundabout

Commit 052a1a49371c

Commit `052a1a49371c`