monolith

public

Star0

Fork 0

Watch0

106 commits 1 branch 0 tags 0 releases1.5 MiB

Commit `e1a086bc100d`

tarball

atagen <boss@atagen.co>2026-10-17 06:25 UTC

1 file changed+117-2

nix: add a NixOS module and make the package run outside the devshell

ash opens libvulkan at runtime, so the built binary only worked where LD_LIBRARY_PATH pointed at the loader. The module follows wry's, a session entry, portals and an optional CAP_SYS_NICE wrapper for SCHED_RR and the realtime queue.

Modified file: flake.nix+117 additions−2 deletions@@ -24,7 +24,9 @@
           craneLib = crane.mkLib pkgs;
           src = lib.cleanSourceWith {
             src = ./.;
-            filter = path: type: (craneLib.filterCargoSources path type) || lib.hasInfix "/shaders" path || lib.hasInfix "/res" path;
+            filter =
+              path: type:
+              (craneLib.filterCargoSources path type) || lib.hasInfix "/shaders" path || lib.hasInfix "/res" path;
             name = "source";
           };
           lavapipeIcd = "${pkgs.mesa}/share/vulkan/icd.d/lvp_icd.${pkgs.stdenv.hostPlatform.parsed.cpu.name}.json";
@@ -61,6 +63,17 @@
                 install -Dm644 res/monolith-portals.conf -t $out/share/xdg-desktop-portal
                 install -Dm644 res/monolith.desktop -t $out/share/wayland-sessions
               '';
+              # ash opens libvulkan at runtime, so it is not in the linked rpath.
+              postFixup = ''
+                patchelf --add-rpath ${lib.makeLibraryPath [ pkgs.vulkan-loader ]} $out/bin/monolith
+              '';
+              passthru.providedSessions = [ "monolith" ];
+              meta = {
+                description = "A tiling Wayland compositor";
+                license = lib.licenses.eupl12;
+                platforms = lib.platforms.linux;
+                mainProgram = "monolith";
+              };
             }
           );
 
@@ -72,7 +85,11 @@
                 cargoClippyExtraArgs = "--all-targets -- --deny warnings";
               }
             );
-            fmt = craneLib.cargoFmt { inherit src; pname = "monolith"; version = "0.0.0"; };
+            fmt = craneLib.cargoFmt {
+              inherit src;
+              pname = "monolith";
+              version = "0.0.0";
+            };
             test = craneLib.cargoTest (
               commonArgs
               // {
@@ -83,12 +100,110 @@
             );
           };
         };
+      nixosModule =
+        {
+          config,
+          lib,
+          pkgs,
+          ...
+        }:
+        let
+          inherit (lib)
+            getExe
+            literalExpression
+            mkDefault
+            mkEnableOption
+            mkIf
+            mkOption
+            optional
+            types
+            ;
+
+          cfg = config.programs.monolith;
+        in
+        {
+          options.programs.monolith = {
+            enable = mkEnableOption "monolith, a tiling Wayland compositor";
+
+            package = mkOption {
+              type = types.package;
+              default = (mkProject pkgs).package;
+              defaultText = literalExpression "monolith.packages.\${system}.default";
+              description = "The monolith package to use.";
+            };
+
+            realtime-scheduling = mkOption {
+              type = types.bool;
+              default = true;
+              description = ''
+                Wrap the monolith binary with CAP_SYS_NICE so its compositor thread runs
+                SCHED_RR and its Vulkan queue gets realtime global priority. monolith clears
+                the capability from everything it launches.
+              '';
+            };
+
+            xwayland.enable = mkEnableOption "Xwayland, started on the first X11 client" // {
+              default = true;
+            };
+
+            extraPackages = mkOption {
+              type = with types; listOf package;
+              default = with pkgs; [
+                foot
+                fuzzel
+                swaylock
+                wl-clipboard
+              ];
+              defaultText = literalExpression "with pkgs; [ foot fuzzel swaylock wl-clipboard ]";
+              description = "Extra packages to be installed system wide.";
+            };
+          };
+
+          config = mkIf cfg.enable {
+            environment.systemPackages = (optional (!cfg.realtime-scheduling) cfg.package) ++ cfg.extraPackages;
+
+            programs = {
+              dconf.enable = mkDefault true;
+              xwayland.enable = mkIf cfg.xwayland.enable (mkDefault true);
+            };
+
+            security = {
+              polkit.enable = true;
+              pam.services.swaylock = { };
+
+              wrappers = mkIf cfg.realtime-scheduling {
+                monolith = {
+                  owner = "root";
+                  group = "root";
+                  permissions = "a+rx";
+                  source = getExe cfg.package;
+                  capabilities = "cap_sys_nice+p";
+                };
+              };
+            };
+
+            xdg.portal = {
+              enable = mkDefault true;
+              configPackages = mkDefault [ cfg.package ];
+              extraPortals = [
+                pkgs.xdg-desktop-portal-gtk
+                pkgs.xdg-desktop-portal-wlr
+              ];
+            };
+
+            services.displayManager.sessionPackages = [ cfg.package ];
+          };
+        };
     in
     {
       packages = forAllSystems (pkgs: {
         default = (mkProject pkgs).package;
       });
 
+      overlays.default = final: _: { monolith = (mkProject final).package; };
+
+      nixosModules.default = nixosModule;
+
       checks = forAllSystems (pkgs: (mkProject pkgs).checks);
 
       devShells = forAllSystems (

monolith

Commit e1a086bc100d

Commit `e1a086bc100d`