monolith

# Runs monolith nested on the host session with real clients and checks what

# they see. Run from the repo root inside `nix develop`, after

# `cargo build -p monolith && cargo build -p monolith-protocols --example workspaces`.

const TOOLS = [foot xterm xwayland lswt grim swaybg swaylock wlrctl]

def main [--log: path = /tmp/monolith-smoke.log] {

    let tools = $TOOLS | each {|t| $"nixpkgs#($t)" }

    let results = mktemp -t monolith-smoke.XXXXXX

    let script = $env.CURRENT_FILE

    let inner = $"nu -n ($script) inner ($results) ($log)"

    # Some parent shells hand down SIGTERM blocked, so only SIGKILL reliably ends a hung run.

    do -i { ^nix shell ...$tools -c sh -c $"unset VK_DRIVER_FILES; RUST_LOG=monolith=debug timeout -s KILL 60 target/debug/monolith run --backend nested ($inner) > ($log) 2>&1" }

    let rows = open --raw $results | lines | where $it != "" | each {|l| $l | from json }

    rm $results

    if ($rows | is-empty) {

        print $"no results, see ($log)"

        exit 1

    }

    print ($rows | table)

    if ($rows | any {|r| not $r.ok }) { exit 1 }

}

def "main inner" [results: path, log: path] {

    try { scenarios $results $log } catch {|e| {name: "harness", ok: false, detail: $e.msg} | to json -r | $"($in)\n" | save -a $results }

    target/debug/monolith msg quit

}

def scenarios [results: path, log: path] {

    let check = {|name: string, ok: bool, detail: any|

        {name: $name, ok: $ok, detail: ($detail | to text | str trim)} | to json -r | $"($in)\n" | save -a $results

    }

    let windows = {|| target/debug/monolith get state | from json | get windows | length }

    job spawn { foot }

    job spawn { foot }

    job spawn { xterm -e sleep 60 }

    let n = wait-until 10sec {|| (do $windows) == 3 }

    do $check "three windows over ipc" ($n) (do $windows)

    let listed = lswt | lines | skip 1 | length

    do $check "toplevel list shows them" ($listed == 3) $listed

    let ws = do { timeout 1 target/debug/examples/workspaces } | complete | get stdout

    do $check "ext-workspace sends a snapshot" ($ws | str contains "workspace") ($ws | lines | length)

    let shot = mktemp -t smoke-XXXXXX.png

    let full = grim $shot | complete

    do $check "output capture" ($full.exit_code == 0 and (ls $shot | get 0.size) > 0b) $full.stderr

    let id = lswt -j | from json | get toplevels.0.identifier

    let one = grim -T $id $shot | complete

    do $check "toplevel capture" ($one.exit_code == 0) $one.stderr

    rm $shot

    wlrctl toplevel close app_id:XTerm

    let closed = wait-until 5sec {|| (do $windows) == 2 }

    do $check "wlr-foreign-toplevel close" $closed (do $windows)

    job spawn { swaybg -c "#336699" }

    let layer = wait-until 5sec {|| open --raw $log | str contains 'namespace="wallpaper"' }

    do $check "layer surface mapped" $layer ""

    job spawn { swaylock -c 000000 }

    let locked = wait-until 5sec {|| open --raw $log | str contains "session locked" }

    do $check "session lock" $locked ""

}

def wait-until [limit: duration, cond: closure] {

    let until = (date now) + $limit

    loop {

        if (do $cond) { return true }

        if (date now) > $until { return false }

        sleep 100ms

    }

}